Sammlung SPARQL Anfragen

# Die meistverschlagworteten GND-Einträge vom Typ
# gndo:Person oder einer seiner Unterklassen, denen
# zudem das weibliche Geschlecht zugeordnet wurde.

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?subject ?subjectLabel (COUNT(?work) AS ?Anzahl) WHERE {
  ?type rdfs:subClassOf* gndo:Person .
  ?preferredName rdfs:subPropertyOf gndo:preferredName .
  ?subject a ?type .
  ?work dct:subject ?subject .
  ?subject ?preferredName ?subjectLabel ;
     gndo:gender <https://d-nb.info/standards/vocab/gnd/gender#female> .
}
GROUP BY ?subject ?subjectLabel
ORDER BY DESC(?Anzahl

# Die meistverschlagworteten GND-Einträge vom Typ
# gndo:PlaceOrGeographicName oder einer seiner Unterklassen.

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dcterms: <http://purl.org/dc/terms/>


SELECT ?subject ?subjectLabel (COUNT(?work) AS ?Anzahl)
WHERE {
  ?work dcterms:subject ?subject .
  ?type rdfs:subClassOf* gndo:PlaceOrGeographicName .
  ?subject a ?type ;
            gndo:preferredNameForThePlaceOrGeographicName ?subjectLabel .
} 
GROUP BY ?subject ?subjectLabel

ORDER BY DESC(?Anzahl)

# Welche Schlagwörter sind die häufigsten in Bezug auf 
# einen bestimmten Publikationszeitraum und 
# in Bezug auf Autor:innen mit einem bestimmten Wirkungsort?

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX rdau: <http://rdaregistry.info/Elements/u/>
PREFIX wdrs: <http://www.w3.org/2007/05/powder-s#> 
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdact: <http://rdaregistry.info/termList/RDACarrierType/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX marcRole: <http://id.loc.gov/vocabulary/relators/>
PREFIX schema: <http://schema.org/>

SELECT DISTINCT ?subject ?sw_name (COUNT(?work) AS ?anzahl) WHERE { 

VALUES ?startYear { 1975 } # Beginn der Zeitspanne
VALUES ?endYear { 2025 }  # Ende der Zeitspanne
VALUES ?place { <https://d-nb.info/gnd/4031483-2> } # Wirkungsort (hier: Köln)

?work dct:subject ?subject ;
      dct:creator ?author; 
	  dct:issued ?year .
	  
FILTER ( xsd:integer(?year) >= ?startYear && xsd:integer(?year) < ?endYear ) .

?author gndo:placeOfActivity ?place .
?subject gndo:preferredNameForTheSubjectHeading ?sw_name .
  OPTIONAL { ?subject gndo:preferredNameForThePlaceOrGeographicName ?sw_name .
 }
  OPTIONAL { ?subject gndo:preferredNameForThePerson ?sw_name .
 }
}

GROUP BY ?subject ?sw_name 
ORDER BY DESC(?anzahl)
LIMIT 100

# Ko-Okkurenzen von Schlagwörtern

PREFIX gndo: <https://d-nb.info/standards/elementset/gnd#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX gnd: <https://d-nb.info/gnd/>
PREFIX rdau: <http://rdaregistry.info/Elements/u/>
PREFIX wdrs: <http://www.w3.org/2007/05/powder-s#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX bibo: <http://purl.org/ontology/bibo/>
PREFIX rdact: <http://rdaregistry.info/termList/RDACarrierType/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

SELECT ?subject ?sw_name (COUNT(?work) AS ?Häufigkeit) WHERE {
  VALUES ?gndId  { <https://d-nb.info/gnd/4054498-9> }. # Hier GND-ID austauschen
  ?work dct:subject ?gndId ;
        dct:subject ?subject .
		FILTER (?subject != ?gndId)
  ?subject gndo:preferredNameForTheSubjectHeading ?sw_name .
  OPTIONAL { ?subject gndo:preferredNameForThePlaceOrGeographicName ?sw_name .
 }
  OPTIONAL { ?subject gndo:preferredNameForThePerson ?sw_name .
 }
}
GROUP BY ?subject ?sw_name 
ORDER BY DESC(?Häufigkeit)
LIMIT 20